Line Angle

[Ken McCall The Boeing Co]

Need to extract the angle of an existing line and load it to a variable in my VB.Net Nethook. Thank You

[Mick George]

Ken,

This should do the trick.

Public Overrides Function Run(param As Integer) As MCamReturn

        '' Make sure there is a line availble for selection
        Dim mask As New GeometryMask(False, True, False, False, False, False, False)

        '' Sanity check
        If Not SearchManager.GetGeometry(mask).Any() Then
            '' Not like this....
            DialogManager.OK("There are no lines in current drawing for selection", "Select a Line")
            Return MCamReturn.FunctionExit
        End If

        '' Keep selecting
        While True

            '' Ok to go, Prompt user for a line
            Dim geometry = SelectionManager.AskForGeometry("Select a line", mask)

            '' Sanity check
            If geometry Is Nothing Then
                '' Likely user cancelled so bail
                Exit While
            End If

            '' Cast geometry type to a line
            Dim line = DirectCast(geometry, LineGeometry)

            '' Get the rise
            Dim dx As Double = line.Data.Point2.x - line.Data.Point1.x
            Dim dy As Double = line.Data.Point2.y - line.Data.Point1.y

            '' Define a new point
            Dim point = new Point2D(dx, dy)

            '' Get the angle
            Dim degrees = VectorManager.AngleDegrees(point)

            '' Display, formatted to 4 decimal places
            DialogManager.OK("Angle of selected line is " + degrees.ToString("###.####"), "Result")

            '' Unselect geometry
            SelectionManager.UnselectAllGeometry()

            '' Refresh
            GraphicsManager.Repaint()

        End While

        Return MCamReturn.NoErrors

    End Function

 

[Ken McCall The Boeing Co]

Hi Mick:

               Your code works great, I was able to take parts of it and add them to my nethook and get it to work.

                                 Thank You