Get Username in VB?

[MLewis]

Is it possible to get the logged on user's name with VBS? In other applications I can get it with Username = Environ("USERNAME")

 

Thanks....

[Roger Martin from CNC Software]

This?

Topic: XP Username in NC Program

[Bullines]

quote:

---

Is it possible to get the logged on user's name with VBS?

---

Yes, consider something like this:

 

code:

---

' Kick off the script

Call Main()

 

 

' Purpose: the main subroutine

Sub Main()

Dim objNetwork ' Network object

Dim strUserName ' current user name

 

 

' Retrieve the username of the person currently logged into the

' computer. Greet the person with their username.

Set objNetwork = WScript.CreateObject("WScript.Network")

strUserName = objNetwork.UserName

 

ShowString "Hi there! You're logged in as " & strUserName

 

 

' Cleanup

Set objNetwork = Nothing

End Sub

---

It uses the Network functions available to the Windows Scripting Host. You could use WMI instead, but people not running WinXP would have to install WMI in order for it to work. Using the Network WSH stuff is almost guaranteed to work on all Windows versions.

 

HTH

[MLewis]

Getting a Variable is undefined: WScript

We're running XP Do I need to install WSH?

[Bullines]

Oops, I forgot that this is running inside of Mastercam. My bad Change:

 

code:

---

Set objNetwork = WScript.CreateObject("WScript.Network")

---

to:

 

code:

---

Set objNetwork = CreateObject("WScript.Network")

---

That should do it.

[MLewis]

Thanks, your help is always appreciated!!!!!!

[Bullines]

Glad to hear that it works. Good thing you didn't have to resort to WMI. It's powerful, but ugly. Here's what a WMI version of the same script might look like:

 

code:

---

' Kick off the script

Call Main()

 

' Purpose: the main subroutine

Sub Main()

Dim strComputer ' computer name to query

Dim ojbWMI ' WMI object

Dim colResult ' results from the query

Dim strUserName ' current user name

 

 

' This computer.

strComputer = "."

 

' Retrieve the username of the person currently logged into the

' computer. Greet the person with their username.

Set objWMI = GetObject("winmgmts:" _

& "{impersonationLevel=impersonate}!" _

& strComputer & "rootcimv2")

 

Set colResult = objWMI.ExecQuery("Select * from Win32_ComputerSystem")

 

' There _should_ only be one.

For Each objComputer in colResult

strUserName = objComputer.UserName

Next

 

ShowString "Hi there! You're logged in as " & strUserName & "."

 

' Cleanup

Set objWMI = Nothing

Set colResult = Nothing

End Sub

---

Nasty, eh? The only benefit is that it'll display the workgroup/domain associated with the username.