Visual Basic File for color selection

[GibbsMachineCorp]

Hello all. I was wondering if someone could get me help with a simple vbs file that would select geo by color? I'm new to vbs files and I'm trying to learn how write and use them to help me speedup some of my processes. Thanks in advance.

 

X6 MU1

XP2000

[Roger Martin from CNC Software]

1> Look thru the sample VBS files in the Shared mcamx6\VB folder.

2> Look at the VBScript.htm file in the \Program Files\mcamx6\help folder.

 

' -- Search thr the database for entities 'by Color' --

' -- Start Script
Call Main()


' ///////////////
' Sub Declaration
' ///////////////
Sub Main()         

	Dim msg
Dim entityType
Dim bRet
Dim matchColor
Dim entityCounter
Dim pointCounter, lineCounter, arcCounter	
Dim searchSelMask 
Dim searchEntMask
Dim entityColor


if Not askColor(matchColor) Then
	Exit Sub
End If

' -- Initialize
entityCounter = 0
pointCounter = 0
lineCounter = 0
arcCounter = 0

searchSelMask = mc_alive 'Or mc_selected
searchEntMask = mc_pointtype Or mc_linetype Or mc_arctype

' -- Search through the database  looking 
' -- for all 'alive' Point/Lines/Arcs
bRet = StartDBSearch(searchSelMask, searchEntMask)

' -- Loop while we have something
Do While bRet								 
	entityCounter = entityCounter + 1

	entityColor = GetEntityColor()
	If (entityColor = matchColor) Then			

		' -- Find out what type of entity we have
		Select Case GetEntityType      
			Case mc_pointtype					
				pointCounter = pointCounter + 1

			Case mc_linetype 					
				lineCounter = lineCounter + 1

			Case mc_arctype 					
				arcCounter = arcCounter + 1       			
		End Select

	End If

	' -- Get next entity
	bRet = NextDBSearch    
Loop 

msg = "Total # of entities looked at = " & entityCounter & vbCrLf & vbCrLf _
& "Entities matching Color# " & matchColor & vbCrLf _
& "Points = " & pointCounter & vbCrLf _
& "Line = " & lineCounter & vbCrLf _
& "Arc = " & arcCounter
ShowString msg

End Sub