VBS: Reusing code

[Bullines]

In languages like C++, Pascal, Java, etc., it's simple to reuse code. C/C++ has the #include directive, Pascal has the uses keyword and Java has the import keyword. If you have code that you find yourself copying and pasting into your scripts over and over, include 'em I know of three ways to do it from VBS, but only 2 of them seem to work with Mastercam, and it's still a little bit tricky.

 

If you have code that doesn't use any Mastercam functions such as file I/O stuff or whatever, you can use WSC (Windows Script Component). WSCs are like C/C++ header files but require a specific syntax that'll look weird at first. You can use the WSC Wizard to create the skeleton of WSC files for you. Here's a little script, let's call it VBMsg.wsc that simply prints out a message using VB's MsgBox() function:

 

code:

---

<?xml version="1.0"?>

<component>

 

<?component error="true" debug="true"?>

<public>

<property name="message">

<get/>

<put/>

</property>

<method name="display">

</method>

</public>

 

<script language="VBScript">

<![CDATA[

Dim strMessage ' the global message

 

' Purpose: retrieve what's currently in the global message variable

' I: (nothing)

' O: the value of the global message variable

Function get_message()

get_message = message

End Function

 

' Purpose: sets the value of the global message variable

' I: new value for the global message

' O: (nothing)

Function put_message(strNewMessage)

strMessage = strNewMessage

End Function

 

' Purpose: displays the global message

' I: (nothing)

' O: (nothing)

Function display()

MsgBox strMessage

End Function

 

]]>

</script>

 

</component>

---

Now from our Mastercam script, say Test1.vbs, we can do the following:

 

code:

---

' -- Start Script

Call Main()

 

' Purpose: the main sub routine

Sub Main()

Dim objTestInclude ' object from our WSC file

 

 

' get a reference to the WSC

Set objTestInclude = GetObject("script:C:FullPathToVBMsg.wsc")

 

' set the message var

objTestInclude.message = "Yo, from me!"

 

' run the function that displays the message var

objTestInclude.display

 

' clean up

Set objTestInclude = Nothing

End Sub

---

I haven't found a way to run Mastercam VBS functions from WSC yet. In that case, you can create your own include function that uses the ExecuteGlobal statement. Let's say I have a file called BullinesArc.txt that contains code to simply create an arc at origin with a diameter of 4:

 

code:

---

' Purpose: creates an arc at origin with a diamter of 4

' I: (nothing)

Sub BullinesCreateArc()

Dim nRet ' return value of CreateArc()

Dim arcTheArc ' the new arc

 

' get a reference to a Mastercam arc object

Set arcTheArc = New McAr

 

' set the parameters of th earc

arcTheArc.X = 0

arcTheArc.Y = 0

arcTheArc.Z = 0

arcTheArc.R = 2

arcTheArc.SA = 0

arcTheArc.SW = 360

 

' create the new arc

nRet = CreateArc(arcTheArc, mcCONSTRUCTION_COLOR_CURRENT, mcCONSTRUCTION_LEVEL_CURRENT)

 

' clean up

Set arcTheArc = Nothing

End Sub

---

Then call our Include() sub routine as soon as we enter our Mastercam script, Test2.vbs so that we can use the function in BullinesArc.txt:

 

code:

---

' -- Start Script

Call Main()

 

 

' Purpose: Include code from an external file

' I: full path to the file to be included

' O: (nothing)

Sub Include(FilePath)

Const ForReading = 1, TristateUseDefault = -2, DoNotCreateFile = False ' just like in VB

Dim objFSO ' FileSystem object

Dim objCurrFile ' File object

 

' get a reference to the objFSO

Set objFSO = CreateObject("Scripting.FileSystemObject")

 

If (objFSO.FileExists(FilePath)) Then ' the include file is there

If (objFSO.GetFile(FilePath).Size > 0) Then ' the include file actually has something in it

' get a reference to the file object using the include file

Set objCurrFile = objFSO.OpenTextFile(FilePath, ForReading, False, TristateUseDefault)

 

' allow our imported code to run

ExecuteGlobal(objCurrFile.ReadAll): objCurrFile.Close

End If

End If

 

' clean up

Set objFSO = Nothing

Set objCurrFile = Nothing

End Sub

 

 

' Purpose: the main function

Sub Main()

' include the file

Include("C:FullPathToBullinesArc.txt")

 

' call BullinesCreateArc() from the included file

Call BullinesCreateArc()

End Sub

---

Hopefully, this'll come in handy

[bryan314]

ctrl-c / ctrl-v works for me.

 

Just being a smartass.

 

Bryan

[Bullines]

Your CPP files must be massive if you're copying and pasting all of those Mastercam header files in LOL

[bryan314]

Tired fingers too.

Go through about 2 keyboards a month.

 

Bryan

[Mick from CNC Software Inc.]

Bullines,

 

I had not seen that wizard before, thanks

 

FYI, if you right click in the script editor you can select to insert an Include function, I use this for a lot of my scripts.

[Bullines]

I didn't see that there, Mick. I guess my second example above is just the "dirty-hands" equivalent of that

 

Kewl