Gundrill cycle for Heidenhain

[Henk]

For our DMU-70eVo with Heidenhain iTNC-530 controller i made an gundrill cycle that i can share.

 

quote:

---

BEGIN PGM GUNDRILL MM

Q251 = Q203 + Q200 ;SAFETY CLEARANCE

Q252 = Q203 + Q358 ;PILOT DEPTH

Q252 = Q252 + 1 ;INFEED DEPTH

Q253 = Q203 + Q201 ;DEPTH

Q254 = Q203 + Q204 ;2ND SAFETY CLEARANCE

;

; CHECK DRILL TYPE

FN9: IF Q351 EQU 0 GOTO LBL 1

FN9: IF Q351 EQU 1 GOTO LBL 1

M00 ; ERROR : WRONG VALUE Q351

;

LBL 1

L ZQ251 R0 FMAX M ;RAPID TO SAFETY CLEARANCE

L ZQ252 R0 F150 M04 ;INFEED IN PILOT REVERSE SPINDLE LOW FEED

M03 M09 ;SPINDLE IN DRILL DIRECTION COOLANT STILL OFF

;

FN11: IF Q360 GT +4700 GOTO LBL 2

;

Q359 = 600 ;START RPM 1 FOR RAMPING UP

CALL LBL 3

;

LBL 2

Q359 = 4705 ;START RPM 2 FOR RAMPING UP

;

LBL 3

TOOL CALL Z SQ359

CYCL DEF 9.0 DWELL TIME

CYCL DEF 9.1 DWELL 0.1

Q359 = Q359 + 200 ;RAMP UP RPM

FN12: IF Q359 LT Q360 GOTO LBL 3

;

TOOL CALL Z SQ360 ;DRILL RPM

M07 ;SPINDLE COOLANT ON

CYCL DEF 9.0 DWELL TIME

CYCL DEF 9.1 DWELL 1

L ZQ253 R0 FQ206 ;FEED TO HOLE DEPTH

L IZ+0.5 R0 ;DRILL 0.5MM FREE FROM BOTTOM

CYCL DEF 9.0 DWELL TIME

CYCL DEF 9.1 DWELL Q211

;

FN9: IF Q351 EQU 1 GOTO LBL 4 ;SELECTION RETRACT MODE

;

M05 M09 ;STOP SPINDLE AND COOLANT

L ZQ254 R0 F10000 M ;RETRACT TO 2ND SAFETY CLEARANCE

CALL LBL 5

;

LBL 4

L ZQ252 R0 F3000 M ;RETRACT TO PILOT DEPTH

TOOL CALL Z S500 ;RPM LOW

L ZQ203 R0 F150 M ;RETRACT TO SURFACE COORDINATE

M05 M09 ;STOP SPINDLE AND COOLANT

L ZQ254 R0 F10000 M ;RETRACT TO 2ND SAFETY CLEARANCE

;

LBL 5

TOOL CALL Z S500 ;RPM LOW

M04 ;SPINDLE REVERSE

END PGM GUNDRILL MM

---

If not exist, create an map called ‘MACRO’ in the controller and place there the program

 

How to use:

quote:

---

-

9 TOOL CALL 20600 Z S531

* - PILOTDRILL-6.0-IK DIA:+6.

10 TOOL DEF 26060

11 L Z-1. R0 FMAX M91

12 ; PILOT HOLES

13 CALL PGM TNC:MACROBEMA.H ;(NO)

14 L X-22. Y+112.5 R0 FMAX M03 M07

15 L Z+130. R0 FMAX M

16 CYCL DEF 203 UNIVERSAL DRILLING~

Q200=+2. ; SAFETY CLEARANCE~

Q201=-12. ; DEPTH~

Q206=32 ; FEED RATE FOR PLUNGING~

Q202=+12. ; INFEED DEPTH~

Q210=+0. ; DWELL TIME AT TOP~

Q203=+120. ; SURFACE COORDINATE~

Q204=+10. ; 2ND SAFETY CLEARANCE~

Q212=+0. ; DECREMENT~

Q213=+0. ; BREAKS~

Q205=+0.5 ; MIN. INFEED DEPTH~

Q211=+0.1 ; DWELL TIME AT DEPTH~

Q208=30000 ; RETRACTION FEED RATE~

Q256=+0.6 ; DIST. FOR CHIP BRKNG

17 L M99

18 L X+10. R0 FMAX M99

19 L X+22. R0 FMAX M99

20 L Z+130. R0 FMAX M

21 M09

-

-

25 TOOL CALL 26060 Z S500 ;RPM FOR INFEED IN PILOT

* - GUNDRILL-6.0x210 DIA:+6.

26 L Z-1. R0 FMAX M91

27 ; LANGGAT 6 DEPTH 165

28 L X-22. Y+113.5 R0 FMAX M04 ;REVERSE DIRECTION FOR INFEED IN PILOT

29 L Z+130. R0 FMAX M

30 ;GUNDRILL PARAMETERS

Q200=+2. ; SAFETY CLEARANCE (POS)

Q201=-185. ; DEPTH (NEG)

Q203=+120. ; SURFACE COORDINATE

Q204=+10. ; 2ND SAFETY CLEARANCE (POS)

Q206=11 ; FEED RATE FOR PLUNGING

Q211=+0.1 ; DWELL TIME AT DEPTH

Q351=0 ; DRILL TYPE (0/1)

Q358=-12. ; PILOT DEPTH (NEG)

Q360=2546 ; DRILL RPM

31 CYCL DEF 12.0 PGM CALL

32 CYCL DEF 12.1 PGM TNC:MACROGUNDRILL.H ;(NO)

33 L M99

34 L X+10. R0 FMAX M99

35 L X+22. R0 FMAX M99

36 L Z+130. R0 FMAX M

37 M09

---

- This is a metric program, for inches it need some edits

- Our spindle has an switch point at 4700 RPM, for that there are 2 start RPM's

- DRILL TYPE '0' is for gundrills

- DRILL TYPE '1' is for overlength spiral drills

 

Have fun