X3 How to send Lathe home with G28

[mroy0404]

Hi Guys

 

 

I need your help, we are using X3 an need to have MPLmaster output G28 on 2 lines like the example below.

 

 

Mplmaster output:

G28 U0. V0. W0.

 

 

What we need to have output:

G28U0.

G28V0.W0.

 

Thanks for your help in advance.

[Colin Gilchrist]

You need to make the following changes in your post.

 

Find the ltlchg$ post block.

 

ltlchg$          #Toolchange, lathe
     toolchng = one
     gcode$ = zero
     copy_x = vequ(x$)
     pcc_capture   #Capture LCC ends, stop output RLCC
     c_rcc_setup$   #Save original in sav_xa and shift copy_x for LCC comp.
     pcom_moveb    #Get machine position, set inc. from c1_xh
     c_mmlt$        #Position multi-tool sub, sets inc. current if G54...
     ptoolcomment
     comment$
     if home_type < two, #Toolchange G50/home/reference position
       [
       sav_xh = vequ(copy_x)
       sav_absinc = absinc$
       absinc$ = zero
       start_xh = vequ(xh$)        
       pmap_home   #Get home position, xabs
       ps_inc_calc #Set start position, not incremental
       #Toolchange home position
       if home_type = one,
         pbld, n$, *sgcode, pwcs, pfxout, pfyout, pfzout, e$
       else,
         [
         #Toolchange g50 position
         pbld, n$, *sg28ref, "U0.", [if y_axis_mch, "V0."], "W0.", e$
         if home_type = zero, pbld, n$, *sg50, pfxout, pfyout, pfzout, e$
         ]
       pe_inc_calc #Update previous
       absinc$ = sav_absinc
       copy_x = vequ(sav_xh)
       ]

 

You need to break up the line with the '*sg28ref' code. Change that line to the following two lines:

 

pbld, n$, *sg28ref, "U0.", e$      #<-----ADDED ', e$' after U0.
n$, *sg28ref, [if y_axis_mch, "V0."], "W0.", e$    #<----- ADDED NEW LINE FOR G28 V0. W0. output

[Colin Gilchrist]

You will also need to make the same change to the pl_retract post block

 

pl_retract      #Retract tool based on next tool gcode, lathe (see ptoolend)
     cc_pos$ = zero
     if home_type = one,
       [
       xh$ = vequ(start_xh)
       pmap_home   #Get home position, xabs
       ps_inc_calc #Set inc.
       pbld, n$, psccomp, e$
       if css_actv$ & css_end_rpm & not(lathe_stop | synch_flg | n1_gcode = 1003 | n1_posttype <> posttype$ | n1_spindle_no <> spindle_no$),
         [
         pspindle
         prpm
         ]
       pcan1, pbld, n$, *sgcode, pfxout, pfyout, pfzout, [if drop_offset, *toolno], strcantext, e$
       if lathe_stop | synch_flg | n1_gcode = 1003 | n1_posttype <> posttype$ | n1_spindle_no <> spindle_no$,
         [
         pbld, n$, pnullstop, e$
         ]
       ]
     else,
       [
       #Retract to reference return
       pbld, n$, `sgcode, psccomp, e$
       if home_type = m_one & drop_offset, pbld, n$, *toolno, e$
       if css_actv$ & css_end_rpm & not(lathe_stop | synch_flg | n1_gcode = 1003 | n1_posttype <> posttype$ | n1_spindle_no <> spindle_no$),
         [
         pspindle
         prpm
         ]        
       pcan1, pbld, n$, *sg28ref, "U0.", e$    #<---- START CHANGES HERE
       n$, *sg28ref, [if y_axis_mch, "V0."], "W0.", strcantext, e$   #<----- ADD THE FOLLOWING LINE

       if lathe_stop | synch_flg | n1_gcode = 1003 | n1_posttype <> posttype$ | n1_spindle_no <> spindle_no$,
         [
         pbld, n$, pnullstop, e$
         ]
       if home_type > m_one & drop_offset, pbld, n$, *toolno, e$

[mroy0404]

Thank you for the help, all is working just the way I need it too. My life is that much better now!!!

[Colin Gilchrist]

Awesome, glad to hear it is working for you...