mpmaster problem

[Jmick]

Just had my post worked on to reduce the amount of characters that can be posted in the header per line (Haas only allows 80 characters)and now have G94s showing in every op. Where is this located in the mpmaster post? TIA.

[Guest CNC Apps Guy 1]

So it did not put in G94 before you had the post worked on and it puts out G94?

[Jmick]

I had my own mpmaster from x3 then they gave me one from x4 with the changes mine had in it plus these g94's

[Guest CNC Apps Guy 1]

sg94 is the call in the post, but you really want to be careful editing it.

[Rob @ Target Machine]

I think I remember what I had to do to stop this constant G94 output.

I'll double check in the morning, but I'm pretty sure this is what I had to do.

 

ptlchg_com      #Tool change common blocks  #Original postblock
     if force_output | sof,
       [
       result = force(ipr_type,ipr_type)
       result = force(absinc$,absinc$)
       result = force(plane$,plane$)
       ]
     pcom_moveb



ptlchg_com      #Tool change common blocks  #Edited postblock
     #if force_output | sof,
     if force_output,
       [
       #result = force(ipr_type,ipr_type)
       result = force(absinc$,absinc$)
       result = force(plane$,plane$)
       ]
     pcom_moveb

 

That should get rid of all but the first G94. So we'll output that in our safety line.

 

psof$            #Start of file for non-zero tool number
     ptravel
     pwritbuf5
     pcuttype
     toolchng = one
     if ntools$ = one,
       [
       #skip single tool outputs, stagetool must be on
       #stagetool = m_one
       !next_tool$
       ]
     tooltotal = rbuf(4,0)  #Reads total tool and null tool changes
     if toolcountn <= tooltotal, nexttool = rbuf(4,toolcountn)
     else, nexttool = first_tool$

     if tool_table = 2, ppredstck
     if tool_table = 3, pmetastck

     spaces$=0
     if output_z = yes$ & tcnt > 1,
       [
       scomm_str, "OVERALL MAX - ", *z_tmax, scomm_end, e$
       scomm_str, "OVERALL MIN - ", *z_tmin, scomm_end, e$
       ]
     spaces$=sav_spc

     if plane$ < 0 | opcode$ = 3 | opcode$ = 16, plane$ = 0
     #pbld, n$, *sgcode, *sgplane, *smetric, "G40", "G80", *sgabsinc, e$          # Comment this out
                                                                                  # Add these two lines
     ipr_type = zero		                                                   # <--------------				
     pbld, n$, *sgfeed, *sgcode, *sgplane, *smetric, "G40", "G80", *sgabsinc, e$  # <-- Safety line (set modals)

     sav_absinc = absinc$
     absinc$ = one
     if wcstype <= one, #Work coordinate system
       [
       pfbld, n$, sgabsinc, *sg28, "Z0.", e$
       pfbld, n$, *sg28, "X0.", "Y0.", e$
       pfbld, n$, "G92", *xh$, *yh$, *zh$, e$
       ]
     else,
       [
       pbld, n$, sgabsinc, *sg28, "Z0.", e$
       ]
     absinc$ = sav_absinc
     sav_mi9 = mi9$
     sav_workofs = workofs$
     if sav_workofs < 0, sav_workofs = 0
     ptlchg_com
     sof = 0

[Jmick]

Thanks Rob that did the trick.

[Rob @ Target Machine]

Old forum cheers

 

Always glad to help.